home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - ProDOS 8 / P8C004.dsk / KERMIT.SETUP.bas < prev    next >
BASIC Source File  |  2012-02-16  |  5KB  |  99 lines
  1. 10  REM KERMIT 3.86 INIT FILE SETUP - LES FERCH - UBC
  2. 20 D$ =  CHR$(4):G$ =  CHR$(7)
  3. 30 DOS =  PEEK(43624) = 1  OR  PEEK(43624) = 2
  4. 40 Y$ = "Y" + CHR$(8):N$ = "N" + CHR$(8)
  5. 50  HOME : PRINT "THIS PROGRAM CREATES A FILE CALLED"
  6. 60  PRINT "'KERMIT.INIT' CONTAINING A SET OF"
  7. 70  PRINT "COMMANDS TO CONFIGURE KERMIT TO SUIT"
  8. 80  PRINT "YOUR EQUIPMENT AND PREFERENCES.": POKE 34,5
  9. 90  GOSUB 700: GOSUB 730
  10. 100  HOME : PRINT "CHANGE ESCAPE CHARACTER TO ESC? ";Y$;
  11. 110 Y = 1: GOSUB 760
  12. 120  IF R  THEN  GOSUB 740: PRINT "SET ESCAPE 1B": GOSUB 730
  13. 130  PRINT "XON/XOFF FLOW CONTROL? ";N$;:Y = 0: GOSUB 760
  14. 140  IF R  THEN  GOSUB 740: PRINT "SET FLOW XON": GOSUB 730
  15. 150  PRINT : PRINT "TYPE OF TERMINAL EMULATION"
  16. 160 A$(1) = "VT52":A$(2) = "VT100":A$(3) = "NONE":A$(4) = "MONITOR"
  17. 170 U = 4:V = 2:W$ = "TERMINAL": GOSUB 890: GOSUB 820
  18. 180  GOSUB 740: PRINT "SET TERMINAL ";A$(S): GOSUB 730
  19. 190  IF S < >2  THEN  PRINT : GOTO 270
  20. 200  PRINT : PRINT "VT100 CURSOR KEYS? ";Y$;:Y = 1: GOSUB 760
  21. 210  IF R  THEN  GOSUB 740: PRINT "SET CURSOR-KEYS-VT100 ON": GOSUB 730
  22. 220  PRINT "HAVE A NUMERIC KEYPAD? ";N$;:Y = 0: GOSUB 760
  23. 230  IF   NOT R  THEN  GOTO 260
  24. 240  GOSUB 740: PRINT "SET KEYPAD ON"
  25. 250  PRINT "SET APPLICATION-MODE ON": GOSUB 730
  26. 260  PRINT "DELETE SENDS CTRL-H INSTEAD OF DEL? ";N$;:Y = 0: GOSUB 760
  27. 270  IF R  THEN  GOSUB 740: PRINT "SET SWAP ON": GOSUB 730
  28. 280  PRINT : PRINT "DEFAULT TYPE OF FILE TRANSFER"
  29. 290 A$(1) = "APPLESOFT":A$(2) = "BINARY"
  30. 300 A$(3) = "INTEGER":A$(4) = "TEXT"
  31. 310 U = 4:V = 4:W$ = "TYPE": GOSUB 890: GOSUB 820
  32. 320  GOSUB 740: PRINT "SET FILE-TYPE ";A$(S): GOSUB 730
  33. 321  PRINT : PRINT "PARITY:"
  34. 323 A$(1) = "NONE":A$(2) = "EVEN":A$(3) = "ODD":A$(4) = "MARK"
  35. 325 A$(5) = "SPACE"
  36. 327 U = 5:V = 1:W$ = "TYPE": GOSUB 890: GOSUB 820
  37. 329  GOSUB 740: PRINT "SET PARITY ";A$(S): GOSUB 730
  38. 330  PRINT : PRINT "DEFAULT TRANSFER PROTOCOL"
  39. 340 A$(1) = "KERMIT":A$(2) = "XMODEM"
  40. 350 U = 2:V = 1:W$ = "PROTOCOL": GOSUB 890: GOSUB 820
  41. 360  GOSUB 740: IF S = 1  THEN 370
  42. 362  PRINT "SET SEND CR<->CR,LF OFF"
  43. 364  PRINT "SET REC CR<->CR,LF OFF"
  44. 370  PRINT "SET PROTOCOL ";A$(S): GOSUB 730
  45. 380  PRINT : PRINT "MODEM IN SLOT 2? ";Y$;:Y = 1: GOSUB 760
  46. 390  IF R  THEN M = 2: GOTO 410
  47. 400 U = 7:V = 1:W$ = "SLOT": GOSUB 820:M = S
  48. 410  GOSUB 740: PRINT "SET SLOT ";M: GOSUB 730
  49. 420  PRINT : PRINT "PRINTER IN SLOT 1? ";Y$;:Y = 1: GOSUB 760
  50. 430  IF R  THEN M = 1: GOTO 450
  51. 440 U = 7:V = 2:W$ = "SLOT": GOSUB 820:M = S
  52. 450  GOSUB 740: PRINT "SET PRINTER SLOT ";M: GOSUB 730
  53. 460  PRINT : PRINT "MODEM SPEED:"
  54. 470 A$(1) = "300":A$(2) = "600":A$(3) = "1200":A$(4) = "2400"
  55. 480 A$(5) = "4800":A$(6) = "9600":A$(7) = "19200"
  56. 490 U = 7:V = 3:W$ = "SPEED": GOSUB 890: GOSUB 820
  57. 500  GOSUB 740: PRINT "SET BAUD ";A$(S): GOSUB 730
  58. 510  IF  PEEK(64435) < >6  THEN  GOTO 540
  59. 520  GOSUB 740: PRINT "SET KEYBOARD 2E": GOSUB 730
  60. 530  GOTO 580: REM IIE/IIC/IIGS
  61. 540  PRINT : PRINT "KEYBOARD LOWER CASE? ";N$;:Y = 0: GOSUB 760
  62. 550  IF R  THEN  GOSUB 740: PRINT "SET KEYBOARD 2E": GOSUB 730
  63. 560  PRINT "DISPLAY LOWER CASE? ";N$;:Y = 0: GOSUB 760
  64. 570  IF R  THEN  GOSUB 740: PRINT "SET DISPLAY 2E-40": GOSUB 730
  65. 580  PRINT : PRINT "80 COLUMN DISPLAY? ";Y$;:Y = 1: GOSUB 760
  66. 590  IF   NOT R GOTO 640
  67. 600 D3 = 3: PRINT "IN SLOT 3? ";Y$;:Y = 1: GOSUB 760
  68. 610  IF R GOTO 630
  69. 620 U = 7:V = 4:W$ = "SLOT": GOSUB 820:D3 = S
  70. 630  GOSUB 740: PRINT "SET DISPLAY 80-COL ";D3: GOSUB 730
  71. 640  GOSUB 740: PRINT "?";: IF DOS  THEN  PRINT 
  72. 650  GOSUB 730
  73. 660  PRINT : PRINT "CHANGE SOMETHING? ";N$;:Y = 0: GOSUB 760
  74. 670  IF R GOTO 90
  75. 680  POKE 34,0: GOTO 910
  76. 690  PRINT "KERMIT INSTALL ABORTED": GOTO 910
  77. 700  PRINT D$;"OPEN KERMIT.INIT": PRINT D$;"CLOSE"
  78. 710  PRINT D$;"DELETE KERMIT.INIT"
  79. 720  PRINT D$;"OPEN KERMIT.INIT": PRINT D$;"WRITE KERMIT.INIT": RETURN 
  80. 730  PRINT D$;"CLOSE KERMIT.INIT": RETURN 
  81. 740  PRINT D$;"APPEND KERMIT.INIT"
  82. 750  PRINT D$;"WRITE KERMIT.INIT": RETURN 
  83. 760  GET R$:S =  ASC(R$):R = (S = 89)  OR (S = 121)  OR ((S = 13)  AND Y)
  84. 770 W = (S = 78)  OR (S = 110)  OR ((S = 13)  AND   NOT Y):E = (S = 27)
  85. 780  IF   NOT (R  OR W  OR E)  THEN 760
  86. 790  PRINT R$: IF S < >13  THEN  PRINT 
  87. 800  IF E  THEN 690
  88. 810  RETURN 
  89. 820  PRINT "WHICH ";W$;"? (1 - ";
  90. 830  PRINT  CHR$(U +48);") "; CHR$(V +48); CHR$(8);
  91. 840  GET R$:S =  ASC(R$) -48:E = (S =  -21)
  92. 850  IF   NOT E  AND (S < > -35)  AND (S <1  OR S >U)  THEN 840
  93. 860  IF S =  -35  THEN S = V:R$ =  CHR$(S +48)
  94. 870  PRINT R$: PRINT : IF E  THEN 690
  95. 880  RETURN 
  96. 890  PRINT : FOR I = 1 TO U: PRINT  CHR$(I +48);" ";A$(I): NEXT 
  97. 900  PRINT : RETURN 
  98. 910  IF DOS  THEN  END 
  99. 920  PRINT D$;"BYE"